|
|
楼主 小神龙说：
下载地址：
http://1000eb.com/1fw8g
使用说明：
大家好！
这是我写的一个简易抽奖器，希望对大家有帮助，下面我来介绍一下如何使用。
第一个编辑框是输入最小数字，也就是起始值的，要是我们从1到100中抽出5个幸运名次的话，这里我们填写1；
第二个编辑框是填写最大数字，也就是结束值的，我们这里填写100；
第三个编辑框是填写抽出个数，我们这里填写5；
最后的编辑框是填写间隔时间，我们这里需要5秒钟抽出一个就填写5。
以上填写完成后我们就可以点击按钮开始抽奖了，抽奖的时候会有音效提示，还有一些功能在菜单里，大家可以自行查看。
开元代码：
.版本 2
.支持库 iext
.程序集 窗口程序集_启动窗口
.程序集变量 数字, 整数型, , "0"
.程序集变量 最小, 整数型
.程序集变量 最大, 整数型
.程序集变量 个数, 整数型
.程序集变量 时间, 整数型
.程序集变量 记次, 整数型
.子程序 _按钮1_被单击
.局部变量 A, 整数型
.局部变量 B, 整数型
.如果真 (到整数 (编辑框1.内容) ＜ 0 或 编辑框1.内容 ＝ “”)
信息框 (“您最小数字填写不正确或者没有填写，请您正确填写！”, #警告图标, “警告”, 取窗口句柄 ())
编辑框1.内容 ＝ “0”
编辑框1.获取焦点 ()
返回 ()
.如果真结束
.如果真 (到整数 (编辑框2.内容) ＜ 0 或 编辑框2.内容 ＝ “”)
信息框 (“您最大数字填写不正确或者没有填写，请您正确填写！”, #警告图标, “警告”, 取窗口句柄 ())
编辑框2.内容 ＝ “100”
编辑框2.获取焦点 ()
返回 ()
.如果真结束
.如果真 (编辑框1.内容 ＝ 编辑框2.内容)
信息框 (“最小数字和最大数字不可以一样哦！”, #警告图标, “啊哦”, 取窗口句柄 ())
编辑框1.获取焦点 ()
返回 ()
.如果真结束
.如果真 (到整数 (编辑框3.内容) ＜ 1 或 编辑框3.内容 ＝ “”)
信息框 (“您抽出个数填写不正确或者没有填写，请您正确填写！”, #警告图标, “警告”, 取窗口句柄 ())
编辑框3.内容 ＝ “1”
编辑框3.获取焦点 ()
返回 ()
.如果真结束
.如果真 (到整数 (编辑框4.内容) ＜ 0 或 编辑框4.内容 ＝ “”)
编辑框4.内容 ＝ “1”
.如果真结束
A ＝ 到整数 (编辑框1.内容)
B ＝ 到整数 (编辑框2.内容)
.如果真 (A ＞ B)
A ＝ A ＋ B
B ＝ A － B
A ＝ A － B
.如果真结束
.如果真 (B － A ＋ 1 ＜ 到整数 (编辑框3.内容))
信息框 (“您填写的抽出个数超出了最小数字和最大数字的差，请您重新填写！”, #警告图标, “警告”, 取窗口句柄 ())
编辑框3.内容 ＝ “1”
编辑框3.获取焦点 ()
返回 ()
.如果真结束
_清空列表_被选择 ()
播放音乐 (#开始, )
最小 ＝ 到整数 (编辑框1.内容)
最大 ＝ 到整数 (编辑框2.内容)
个数 ＝ 到整数 (编辑框3.内容)
时间 ＝ 到整数 (编辑框4.内容)
时钟1.时钟周期 ＝ 1000
超级列表框1.获取焦点 ()
.子程序 _时钟1_周期事件
.局部变量 I, 整数型
记次 ＝ 记次 ＋ 1
置随机数种子 ()
.如果 (记次 ％ 时间 ＝ 0)
.判断循环首 (按钮1.标题 ≠ “”)
I ＝ 取随机数 (最小, 最大)
.如果真 (检查数字是否存在 (数字, I) ＝ 假)
加入成员 (数字, I)
超级列表框1.插入表项 (, 到文本 (I), , , , )
超级列表框1.现行选中项 ＝ 超级列表框1.取表项数 () － 1
播放音乐 (#抽出, )
标签1.标题 ＝ 到文本 (I)
跳出循环 ()
.如果真结束
.判断循环尾 ()
.否则
标签1.标题 ＝ 到文本 (取随机数 (最小, 最大))
.如果结束
.如果真 (取数组成员数 (数字) ＝ 个数)
播放音乐 (#完成, )
时钟1.时钟周期 ＝ 0
.如果真结束
.子程序 检查数字是否存在, 逻辑型
.参数 被检查数组, 整数型, 数组
.参数 检查数字, 整数型
.局部变量 D, 整数型
.计次循环首 (取数组成员数 (被检查数组), D)
.如果真 (被检查数组 [D] ＝ 检查数字)
返回 (真)
.如果真结束
.计次循环尾 ()
返回 (假)
.子程序 _按钮1_按下某键, 逻辑型
.参数 键代码, 整数型
.参数 功能键状态, 整数型
.如果真 (键代码 ＝ 13 且 功能键状态 ＝ 0)
_按钮1_被单击 ()
.如果真结束
.子程序 _开始抽奖_被选择
_按钮1_被单击 ()
.子程序 _清空列表_被选择
时钟1.时钟周期 ＝ 0
清除数组 (数字)
连续赋值 (0, 最小, 最大, 个数, 时间, 记次)
超级列表框1.全部删除 ()
标签1.标题 ＝ “0.0”
.子程序 _复制列表_被选择
.局部变量 D, 整数型
.局部变量 t, 文本型
t ＝ “抽奖结果” ＋ #换行符
.计次循环首 (取数组成员数 (数字), D)
t ＝ t ＋ 到文本 (数字 [D]) ＋ #换行符
.计次循环尾 ()
置剪辑板文本 (t)
.子程序 _程序退出_被选择
销毁 ()
.子程序 _说明_被选择
信息框 (#说明文本, #信息图标, “说明”, )
.子程序 _关于_被选择
信息框 (“幸运抽奖器 V 1.0” ＋ #换行符 ＋ “作者：小神龙” ＋ #换行符 ＋ “联系QQ：2719957234” ＋ #换行符 ＋ “E-Mail：XiaoShenLong68@sina.com”, #信息图标, “关于”, )
|
|
发表于 2015-9-7 11:21:49
收藏
发表于 2015-9-8 10:50:09
楼主